masputih.com - OLD SITE: CopyPixels

17 November 2008 in ActionScript 3, Demo | permalink

CopyPixels

Here's an example of using BitmapData.copyPixels() to copy a portion of an external image to another Display Object. In his book, Essential AS 3.0, Colin Moock said BitmapData.copyPixels() proved to be 25% - 300% faster than BitmapData.draw().

Click and drag the green rectangle

Sorry, but you do not have the minimum version (9) of flash player required to play this flash movie. You can install or upgrade flash here.

Code

package {
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	import flash.net.URLRequest;

[SWF(width='400', height='300', backgroundColor='#ffffff', frameRate='24')]
	public class CopyPixelDemo extends Sprite{

private const WINDOW_WIDTH:Number = 50;
		private const WINDOW_HEIGHT:Number = 50;

private var _loadedAssetContainer:Sprite;
		private var _loadedBitmapData:BitmapData;
		//a small square at the bottom
		private var _windowBitmap:Bitmap;
		//a draggable sprite that defines the source for copyPixels()
		private var _draggableSprite:Sprite;

public function CopyPixelDemo(){
			_windowBitmap = new Bitmap(new BitmapData(WINDOW_WIDTH,WINDOW_HEIGHT,true,0x00000000));

_draggableSprite = new Sprite();
			_draggableSprite.graphics.beginFill(0x000000,0);
			_draggableSprite.graphics.lineStyle(1,0x00FF00);
			_draggableSprite.graphics.drawRect(0,0,WINDOW_WIDTH,WINDOW_HEIGHT);
			_draggableSprite.graphics.endFill();

loadImage("http://masputih.com/files/colour_blind_10.jpg");

}

//----------------------- IMAGE LOADING
		private function loadImage(url:String):void{
			var loader:Loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.INIT, onLoaderInit);
			loader.load(new URLRequest(url));
		}

private function onLoaderInit(e:Event):void{
			_loadedAssetContainer = new Sprite();
			_loadedAssetContainer.addChild(LoaderInfo(e.target).content);
			_loadedBitmapData = new BitmapData(_loadedAssetContainer.width,_loadedAssetContainer.height,true,0x00000000);
			_loadedBitmapData.draw(_loadedAssetContainer);

_windowBitmap.y = _loadedAssetContainer.height + 20;

addChild(_loadedAssetContainer);
			addChild(_windowBitmap);
			addChild(_draggableSprite);

//do an initial copy to give the window something to show
			_isDragging = true; //fake flag
			copyPixels();

_draggableSprite.addEventListener(MouseEvent.MOUSE_DOWN,drag);
			_draggableSprite.addEventListener(MouseEvent.MOUSE_UP,drop);
			addEventListener(Event.ENTER_FRAME,copyPixels);
		}

//----------------------- DRAG & DROP
		private var _isDragging:Boolean = false;
		private function drag(e:MouseEvent):void{
			_draggableSprite.startDrag(false,new Rectangle(0,0,_loadedAssetContainer.width-_draggableSprite.width,_loadedAssetContainer.height-_draggableSprite.height));
			_isDragging = true;
		}

private function drop(e:MouseEvent):void{
			_draggableSprite.stopDrag();
			_isDragging = false;
		}

//---------------------- COPY PIXELS
		private function copyPixels(e:Event = null):void{
			if(!_isDragging) return;
			_windowBitmap.bitmapData.copyPixels(_loadedBitmapData,_draggableSprite.getRect(_loadedAssetContainer),new Point(0,0));
		}

}
}

Possibly related articles:

Next article:: Skinning FXVideo, The Easy Way
Previous article:: Reconstruction Completed

Comments [1]

1. Nikky , 1145 days ago #

Thank you.

Commenting is closed for this article.

masputih.com - OLD SITE

CopyPixels

Code

Possibly related articles:

Comments [1]

Looking for something ?

Categories

Friends

Books I Read

Resources